home *** CD-ROM | disk | FTP | other *** search
/ Scene Storm / Scene Storm - Volume 1.iso / coding / asm / demos / sinescroll_2 / sine.s < prev   
Text File  |  1980-01-03  |  14KB  |  598 lines
  1. ;==========================================================================
  2. ; 
  3. ; Program Name    : Sine Scroller    { Not-Optimized }
  4. ; 
  5. ; Coded by    : Del/Mayhem
  6. ; Date        : 1989
  7. ; Licence    : Freeware
  8. ;
  9. ; AGA Fixed     : Demo Fixed By Digital Candy, 1996,
  10. ;        : All Absolute Address referencing fixed, AGA patches
  11. ;        : fixed... Tested on 50MhZ A1200/030 (AGA), now works
  12. ;        : correctly from any chip memory region..
  13. ;==========================================================================
  14. *-------------- Try changing the following 5 equates for cool effects
  15.  
  16. speed        =    1        ;Scrolly speed (1,2,4 or 8)
  17. yspace1        =    4        ;Sine spacing (Max 512)
  18. yspeed1        =    8        ;Sine wibble speed (max 512)
  19. sinesize    =    220        ;Depth of sinescroller (max 220)
  20. stoptime    =    4        ;How many seconds scrolly pauses for!
  21.  
  22. *--------------
  23.  
  24. blitwait    macro
  25. .bw\@        btst #6,2(a6)        ;Blitwait macro...
  26.         bne.s .bw\@        ;Wait for blitter to stop
  27.         endm
  28.  
  29.     Section del,code_c        ;Put everything into chip memory!
  30.  
  31. Start    lea variables(pc),a5    ;Variables pointer in A5
  32.     lea custom,a6        ;Custom chip pointer in A6
  33.  
  34.     bsr trash            ;Trash the operating system
  35.     bsr intcustom        ;Init Screen size,modulos etc.
  36.     bsr intbuffer        ;Init double buffer!
  37.     bsr makecop        ;Make the copper list
  38.     bsr initsine        ;Init sinetable!
  39.  
  40.     lea wherecop(pc),a0
  41.     move.l a0,cop1lc(a6)    ;Tell system where copper is...
  42.     move.w copjmp1(a6),d0    ;And start it
  43.     move.w #$87e0,dmacon(a6)    ;Enable Dma.
  44.     move.w #$20,intreq(a6)    ;Clear VBI IRQ bit.
  45.  
  46.    ***********************
  47.    ****** Main loop ******
  48.    ***********************
  49.  
  50. .button    lea custom,a6
  51.     btst #5,intreqr+1(a6)    ;VBI interrupt?
  52.     beq.s .button
  53.     move.w #$20,intreq(a6)    ;Clear VBI IRQ bit.
  54.  
  55.     bsr cls            ;Clear screen!
  56.     bsr dosine        ;Do sine movement!
  57.     blitwait            ;Wait for blitter to stop clearing screen!
  58.     bsr scroll        ;Scroll message!
  59.     bsr blitsine        ;Blit scrolly onto screen
  60.     bsr doublebuffer        ;Double buffer the screen
  61.  
  62.     btst #6,$bfe001        ;Is left mouse button pressed?
  63.     bne.s .button
  64.  
  65.      bsr.s untrash        ;Bring back operating system
  66.     moveq #0,d0        ;Stop a return error!
  67.     rts
  68.     
  69. trash    bset #1,$bfe001        ;Turn power light off
  70.     move.l $4.w,a6
  71.     lea gfxname(pc),a1
  72.     moveq #0,d0
  73.     jsr -552(a6)        ;Open graphics library
  74.     move.l d0,a0
  75.     move.l 38(a0),syscop(a5)    ;Store old system copper address!
  76.  
  77.     lea custom,a6
  78.     move.w intenar(a6),d0    ;Get system IRQ register
  79.     or.w #$8000,d0        ;Set top bit (For enable)
  80.     move.w d0,IRQ(a5)        ;Store it
  81.     move.w dmaconr(A6),d0    ;Get system DMA register
  82.     or.w #$8000,d0        ;Set top bit (For enable)
  83.     move.w d0,DMA(a5)        ;Store it
  84.  
  85.     move.w #$7fff,intena(a6)    ;All irq off
  86.     move.w #$7fff,dmacon(A6)    ;All dma off
  87.     rts
  88.  
  89. untrash    lea custom,a6
  90.     lea variables(pc),a5
  91.  
  92.     move.w #$7fff,$96(a6)    ;Kill DMA
  93.     move.w #$7fff,$9a(a6)    ;Kill IRQ
  94.     move.w DMA(a5),dmacon(A6)    ;Restore system DMA
  95.     move.w IRQ(a5),intena(a6)    ;Restore system IRQ
  96.     move.w #$7fff,intreq(a6)
  97.     clr.w aud0vol(a6)
  98.     clr.w aud1vol(a6)
  99.     clr.w aud2vol(a6)
  100.     clr.w aud3vol(a6)        ;Clear volume registers
  101.  
  102.     move.l syscop(a5),d0    ;Get old system copper address
  103.     move.l d0,cop1lc(a6)    ;And restore it!
  104.     move.l $4.w,a6
  105.     lea intname(pc),a1
  106.     moveq #0,d0
  107.     jsr -552(a6)
  108.     move.l d0,a6
  109.     jsr -390(a6)
  110.     bclr #1,$bfe001        ;Power light back on
  111.     rts
  112.  
  113. setmulti    move.w d7,(a0)+        ;Copper 32 bit write
  114.     swap d0
  115.     move.w d0,(a0)+
  116.     swap d0
  117.     addq.w #2,d7
  118.     move.w d7,(a0)+
  119.     move.w d0,(a0)+
  120.     addq.w #2,d7
  121.     add.l d5,d0
  122.     dbra d6,setmulti
  123.     rts
  124.  
  125. intcustom    clr.w bplcon1(a6)        ;Scroll value
  126.     clr.w bplcon2(a6)        ;Priorities
  127.     clr.w bpl1mod(a6)        ;Modulo A
  128.     clr.w bpl2mod(a6)        ;Modulo B
  129.     move.w #$0038,ddfstrt(a6)    ;Data fetch start
  130.     move.w #$00d0,ddfstop(a6)    ;Data fetch stop
  131.     move.w #$2c81,diwstrt(a6)    ;Window start
  132.     move.w #$2cc1,diwstop(a6)    ;Window stop
  133.     rts
  134.  
  135. makecop    lea wherecop(pc),a0        ;Copperlist address
  136.     
  137.     lea wherespr(pc),a1        ;First do sprites..
  138.     move.l a1,d0
  139.     moveq #7,d6        ;8 sprites
  140.     move.w #$120,d7        ;1st register no.
  141.     moveq #16,d5        ;16 bytes per sprite!
  142.     bsr setmulti
  143.  
  144.     move.l a0,changecop(a5)    ;Store copper address (For double buffer!)
  145.     move.l logbase(a5),d0    ;Bitmap address
  146.     moveq #1-1,d6        ;1 plane
  147.     move.w #$e0,d7        ;1st register no.
  148.     moveq #0,d5        ;Plane length
  149.     bsr setmulti
  150.  
  151.     move.l #$01001200,(a0)+    ;Set 1 bitplane
  152.     move.l #$01800000,(a0)+    ;Colour 0
  153.     move.l #$01820fff,(a0)+    ;Colour 1
  154.     move.l #$01FC0000,(a0)+    ;fetch mode
  155.     move.l #$01060000,(a0)+    ;fetch mode
  156.     
  157.     moveq #-2,d0
  158.     move.l d0,(a0)+        ;Wait for the impossible (END!)
  159.     rts
  160.  
  161.  ************************************
  162.  *********** END OF SETUP ***********
  163.  ************************************
  164.  
  165. intbuffer    move.l bitmap1_ptr,logbase(a5)    ;Init doublebuffer screen 1
  166.     move.l bitmap2_ptr,physbase(a5)    ;Init doublebuffer screen 2
  167.     rts
  168.  
  169. doublebuffer
  170.     move.l logbase(a5),d0
  171.     move.l physbase(a5),logbase(a5)
  172.     move.l d0,physbase(a5)
  173.  
  174.     move.l changecop(a5),a0        ;Update copper!
  175.     moveq #0,d6
  176.     move.w #$e0,d7
  177.     moveq #0,d5
  178.     bsr setmulti
  179.     rts
  180.  
  181. cls    moveq #-1,d0
  182.     move.l d0,bltafwm(a6)        ;First and last word mask
  183.     clr.w bltcon1(a6)            ;No special modes
  184.     clr.w bltdmod(a6)            ;D modulo
  185.     move.w #%0000000100000000,bltcon0(a6)     ;No minterm just enable d!    
  186.  
  187.     move.l logbase(a5),bltdpt(A6)        ;Destination
  188.     move.w #(256<<6)!20,bltsize(a6)    ;256 high by 20 words wide
  189.     rts
  190.  
  191. scroll    tst.w stop(a5)
  192.     ble.s .ok
  193.     subq.w #1,stop(a5)
  194.     rts
  195.  
  196. .ok    bsr blitshift
  197.     subq.w #speed,scrcount(a5)
  198.     ble.s .gog
  199.     rts
  200. .gog    move.w #16,scrcount(a5)        ;Reset counter!
  201.  
  202.     lea text(pc),a2
  203.     move.w messcount(a5),d0        ;Message count
  204. .again    moveq #0,d1
  205.     move.b (a2,d0.w),d1            ;Get char
  206.     bne.s .dlf
  207.     clr.w messcount(a5)
  208.     move.w messcount(a5),d0
  209.     bra.s .again            ;Wrap at a zero
  210.  
  211. .dlf    cmp.w #$ff,d1
  212.     bne.s .nstop
  213.     move.w #stoptime*50,stop(a5)        ;Trigger stop    
  214.     moveq #32,d1
  215.  
  216. .nstop    addq.w #1,messcount(a5)        ;Update scroll offset
  217.     lea scrarea+82,a0
  218.     lea font,a1
  219.  
  220.     sub.w #32,d1            ;Ascii conversion!
  221. .go    cmp.w #20,d1
  222.     blt.s .nnl            ;Next line of chars?
  223.     lea 40*16(a1),a1            ;Move down a line!
  224.     sub.w #20,d1
  225.     bra.s .go
  226. .nnl    add.w d1,d1
  227.     add.w d1,a1            ;Get to char 
  228.  
  229.     moveq #15,d0
  230. .xloop    move.w (a1),(a0)            ;Plot char!
  231.     add.w #42,a0
  232.     add.w #40,a1
  233.     dbra d0,.xloop            ;Loop for 16 high
  234.     rts
  235.  
  236. blitshift    moveq #-1,d0
  237.     move.l d0,bltafwm(a6)
  238.     clr.w bltamod(a6)
  239.     clr.w bltdmod(a6)
  240.     clr.w bltcon1(a6)
  241.  
  242.     move.w #%0000100100000000!$f0,d0
  243.     moveq #speed,d1
  244.     neg.w d1
  245.     moveq #12,d2
  246.     lsl.w d2,d1            ;Work out speed (shift!)
  247.     or.w d1,d0
  248.     move.w d0,bltcon0(a6)        ;D=A Minterm
  249.  
  250.     move.l #scrarea,d0
  251.     move.l d0,bltdpt(A6)        ;Destination
  252.     addq.l #2,d0
  253.     move.l d0,bltapt(a6)        ;Source
  254.  
  255.     move.w #(17<<6)!20,bltsize(a6)
  256.     blitwait
  257.     rts
  258.  
  259. blitsine    clr.w bltcon1(a6)
  260.     move.w #42-2,bltamod(a6)
  261.     move.w #40-2,bltdmod(a6)
  262.     move.w #40-2,bltbmod(a6)
  263.  
  264.     move.l logbase(a5),d0
  265.     move.l d0,bltbpt(a6)        ;Init destination pointers!
  266.     move.l d0,bltdpt(a6)
  267.  
  268.     lea masklook(pc),a0
  269.     lea scrpos(pc),a1
  270.     move.l #scrarea+42,a2
  271.     move.l a2,bltapt(a6)        ;Init source pointer!
  272.     lea bltafwm(a6),a3
  273.     lea bltsize(a6),a4
  274.     move.l a7,stacksave(a5)        ;Save stack!
  275.     lea bltdpt+2(a6),a7
  276.     lea bltapt+2(a6),a5
  277.  
  278.     moveq #20-1,d7            ;20 words
  279.     move.w #(16<<6)!1,d6
  280.     move.w #%0000100100000000!$f0,d5
  281.     move.w #%0000110100000000!$fc,d4
  282.  
  283. .loop    move.w d5,bltcon0(a6)         ;D=A
  284.     move.w (a0)+,(a3)            ;First word mask
  285.     move.w a2,(a5)            ;Source
  286.     move.w (a1)+,(a7)            ;Destination
  287.     move.w d6,(a4)            ;Blitsize
  288.     blitwait
  289.  
  290.     move.w d4,bltcon0(a6)         ;D=A+B
  291.     rept 15
  292.     move.w (a0)+,(a3)            ;First word mask
  293.     move.w a2,(a5)            ;Source
  294.     move.w (a1),bltbpt+2(a6)        ;Destination
  295.     move.w (a1)+,(a7)            ;Destination
  296.     move.w d6,(a4)            ;Blitsize
  297.     blitwait
  298.     endr
  299.  
  300.     addq.w #2,a2            ;Next word along!
  301.     dbra d7,.loop
  302.  
  303.     lea variables(pc),a5
  304.     move.l stacksave(a5),sp
  305.     rts    
  306.  
  307. initsine    lea originalsine(pc),a0
  308.     move.w #511,d0
  309. .loop1    sub.w #128,(a0)+            ;Init original sine
  310.     dbra d0,.loop1
  311.  
  312.     lea originalsine(pc),a0
  313.     lea sine1(pc),a1
  314.     move.w #511,d0
  315. .loop2    move.w (a0)+,d1
  316.     muls.w #sinesize,d1            ;Size!
  317.     asr.w #8,d1
  318.     add.w #sinesize/2,d1
  319.     mulu.w #40,d1            ;Multiple of 40!
  320.     move.w d1,(a1)+            ;Make sinetable!
  321.     dbra d0,.loop2
  322.     rts
  323.  
  324. dosine    lea sine1(pc),a0
  325.     lea scrpos(pc),a1
  326.     move.l logbase(a5),a3
  327.     moveq #20-1,d7            ;20 words wide!
  328.     move.w sinestart1(a5),d0
  329.     move.w #1022,d3
  330.     move.w #yspace1,d4
  331. .loop    
  332.     rept 16
  333.     and.w d3,d0
  334.     move.w (a0,d0.w),d2
  335.     lea (a3,d2.w),a2            ;Add offset 1
  336.     add.w d4,d0            ;Spacing 1
  337.     move.w a2,(a1)+            ;Scroll position!
  338.     endr
  339.  
  340.     addq.w #2,a3            ;Next word along!
  341.     dbra d7,.loop
  342.     sub.w #yspeed1,sinestart1(a5)
  343.     rts
  344.  
  345. intname    dc.b "intuition.library",0
  346. gfxname    dc.b "graphics.library",0
  347.     even
  348.  
  349. text    DC.B " THIS SINE SCROLLER WAS CODED BY DEL. "
  350.     DC.B "   IT ISN'T VERY OPTIMIZED BUT WHO CARES?    "
  351.     DC.B "  TRY CHANGING THE EQUATES AT THE TOP OF THE CODE"
  352.     DC.B " FOR DIFFERENT EFFECTS!!!           "
  353.     DC.B "....... DEL! .......",$FF
  354.     DC.B "                    ",0
  355.     even
  356.  
  357. originalsine
  358.     DC.w 128,129,131,132,134,135,137,138,140,142,143,145,146,148,149
  359.     DC.w 151,152,154,156,157,159,160,162,163,165,166,168,169,171,172
  360.     DC.w 174,175,176,178,179,181,182,184,185,186,188,189,191,192,193
  361.     DC.w 195,196,197,199,200,201,202,204,205,206,207,209,210,211,212
  362.     DC.w 213,215,216,217,218,219,220,221,222,223,224,225,226,227,228
  363.     DC.w 229,230,231,232,233,234,235,236,236,237,238,239,240,240,241
  364.     DC.w 242,243,243,244,245,245,246,246,247,247,248,249,249,250,250
  365.     DC.w 250,251,251,252,252,252,253,253,253,254,254,254,254,255,255
  366.     DC.w 255,255,255,255,255,255,255,255,256,255,255,255,255,255,255
  367.     DC.w 255,255,255,255,254,254,254,254,253,253,253,252,252,252,251
  368.     DC.w 251,250,250,250,249,249,248,247,247,246,246,245,245,244,243
  369.     DC.w 243,242,241,240,240,239,238,237,236,236,235,234,233,232,231
  370.     DC.w 230,229,228,227,226,225,224,223,222,221,220,219,218,217,216
  371.     DC.w 215,213,212,211,210,209,207,206,205,204,202,201,200,199,197
  372.     DC.w 196,195,193,192,191,189,188,186,185,184,182,181,179,178,176
  373.     DC.w 175,174,172,171,169,168,166,165,163,162,160,159,157,156,154
  374.     DC.w 152,151,149,148,146,145,143,142,140,138,137,135,134,132,131
  375.     DC.w 129,127,126,124,123,121,120,118,117,115,113,112,110,109,107
  376.     DC.w 106,104,103,101,99,98,96,95,93,92,90,89,87,86,84
  377.     DC.w 83,81,80,79,77,76,74,73,71,70,69,67,66,64,63
  378.     DC.w 62,60,59,58,56,55,54,53,51,50,49,48,46,45,44
  379.     DC.w 43,42,40,39,38,37,36,35,34,33,32,31,30,29,28
  380.     DC.w 27,26,25,24,23,22,21,20,19,19,18,17,16,15,15
  381.     DC.w 14,13,12,12,11,10,10,9,9,8,8,7,6,6,5
  382.     DC.w 5,5,4,4,3,3,3,2,2,2,1,1,1,1,0
  383.     DC.w 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  384.     DC.w 0,0,0,0,0,1,1,1,1,2,2,2,3,3,3
  385.     DC.w 4,4,5,5,5,6,6,7,8,8,9,9,10,10,11
  386.     DC.w 12,12,13,14,15,15,16,17,18,19,19,20,21,22,23
  387.     DC.w 24,25,26,27,28,29,30,31,32,33,34,35,36,37,38
  388.     DC.w 39,40,42,43,44,45,46,48,49,50,51,53,54,55,56
  389.     DC.w 58,59,60,62,63,64,66,67,69,70,71,73,74,76,77
  390.     DC.w 79,80,81,83,84,86,87,89,90,92,93,95,96,98,99
  391.     DC.w 101,103,104,106,107,109,110,112,113,115,117,118,120,121,123
  392.     DC.w 124,126
  393.  
  394. sine1    ds.w 512
  395.  
  396. masklook    
  397.     rept 20
  398.     dc.w %1000000000000000
  399.     dc.w %0100000000000000
  400.     dc.w %0010000000000000
  401.     dc.w %0001000000000000
  402.     dc.w %0000100000000000
  403.     dc.w %0000010000000000
  404.     dc.w %0000001000000000
  405.     dc.w %0000000100000000
  406.     dc.w %0000000010000000
  407.     dc.w %0000000001000000
  408.     dc.w %0000000000100000
  409.     dc.w %0000000000010000
  410.     dc.w %0000000000001000
  411.     dc.w %0000000000000100
  412.     dc.w %0000000000000010
  413.     dc.w %0000000000000001
  414.     endr
  415.  
  416. bitmap1_ptr:    dc.l    ymem1
  417. bitmap2_ptr:    dc.l    ymem2
  418.  
  419. shftlook    dc.w $09f0,$19f0,$29f0,$39f0,$49f0,$59f0,$69f0,$79f0
  420.     dc.w $89f0,$99f0,$a9f0,$b9f0,$c9f0,$d9f0,$e9f0,$f9f0
  421.  
  422. scrpos    ds.w 320
  423.  
  424.     rsreset
  425. syscop    rs.l 1
  426. irq    rs.w 1
  427. dma    rs.w 1
  428. physbase    rs.l 1
  429. logbase    rs.l 1
  430. changecop    rs.l 1
  431. scrcount    rs.w 1
  432. stop    rs.w 1
  433. messcount    rs.w 1
  434.  
  435. sinestart1 rs.w 1
  436. stacksave    rs.l 1
  437.  
  438. varisize    rs.w 0
  439. Variables    dcb.b varisize,0
  440.  
  441. wherespr    dcb.b 16*8,0    ;128 bytes for hardware sprites
  442. wherecop     dcb.b 2000,0    ;2k for copper list
  443.  
  444.     section bud,data_c
  445. font    incbin scene1:coding/asm/demos_sinescroll_2/font.raw
  446.  
  447.         section cake,bss_C
  448.  
  449. scrarea        ds.b 42*20
  450. ymem1:        ds.b    $2800
  451. ymem2:        ds.b    $2800
  452.  
  453.    *** Equates and data below! ***
  454.  
  455. custom     EQU $dff000
  456. bltddat    EQU $000
  457. dmaconr    EQU $002
  458. vposr    EQU $004
  459. vhposr    EQU $006
  460. dskdatr    EQU $008
  461. joy0dat    EQU $00A
  462. joy1dat    EQU $00C
  463. clxdat    EQU $00E
  464. adkconr    EQU $010
  465. pot0dat    EQU $012
  466. pot1dat    EQU $014
  467. potinp    EQU $016
  468. serdatr    EQU $018
  469. dskbytr    EQU $01A
  470. intenar    EQU $01C
  471. intreqr    EQU $01E
  472. dskpt    EQU $020
  473. dsklen    EQU $024
  474. dskdat    EQU $026
  475. refptr    EQU $028
  476. vposw    EQU $02A
  477. vhposw    EQU $02C
  478. copcon    EQU $02E
  479. serdat    EQU $030
  480. serper    EQU $032
  481. potgo    EQU $034
  482. joytest    EQU $036
  483. strEQU    EQU $038
  484. strvbl    EQU $03A
  485. strhor    EQU $03C
  486. strlong    EQU $03E
  487. bltcon0    EQU $040
  488. bltcon1    EQU $042
  489. bltafwm    EQU $044
  490. bltalwm    EQU $046
  491. bltcpt    EQU $048
  492. bltbpt    EQU $04C
  493. bltapt    EQU $050
  494. bltdpt    EQU $054
  495. bltsize    EQU $058
  496. bltcmod    EQU $060
  497. bltbmod    EQU $062
  498. bltamod    EQU $064
  499. bltdmod    EQU $066
  500. bltcdat    EQU $070
  501. bltbdat    EQU $072
  502. bltadat    EQU $074
  503. dsksync    EQU $07E
  504. cop1lc    EQU $080
  505. cop2lc    EQU $084
  506. copjmp1    EQU $088
  507. copjmp2    EQU $08A
  508. copins    EQU $08C
  509. diwstrt    EQU $08E
  510. diwstop    EQU $090
  511. ddfstrt    EQU $092
  512. ddfstop    EQU $094
  513. dmacon    EQU $096
  514. clxcon    EQU $098
  515. intena    EQU $09A
  516. intreq    EQU $09C
  517. adkcon    EQU $09E
  518. aud0lc    EQU $0A0
  519. aud1lc    EQU $0b0
  520. aud2lc    EQU $0c0
  521. aud3lc    EQU $0d0
  522. aud0len    EQU $a4
  523. aud1len    EQU $b4
  524. aud2len    EQU $c4
  525. aud3len    EQU $d4
  526. aud0per    EQU $a6
  527. aud1per    EQU $b6
  528. aud2per    EQU $c6
  529. aud3per    EQU $d6
  530. aud0vol    EQU $a8
  531. aud1vol    EQU $b8
  532. aud2vol    EQU $c8
  533. aud3vol    EQU $d8
  534. aud0dat    EQU $aa
  535. aud1dat    EQU $ba
  536. aud2dat    EQU $ca
  537. aud3dat    EQU $da
  538. bpl1pth    EQU $0E0
  539. bpl2pth    EQU $0E4
  540. bpl3pth    EQU $0E8
  541. bpl4pth    EQU $0EC
  542. bpl5pth    EQU $0F0
  543. bpl6pth    EQU $0F4
  544. bplcon0    EQU $100
  545. bplcon1    EQU $102
  546. bplcon2    EQU $104
  547. bpl1mod    EQU $108
  548. bpl2mod    EQU $10A
  549. bpldat    EQU $110
  550. sprpt    EQU $120
  551. spr    EQU $140
  552. sd_pos    EQU $00
  553. sd_ctl    EQU $02
  554. sd_dataa     EQU $04
  555. sd_datab     EQU $08
  556. color00    EQU $180
  557. color01     EQU $182
  558. color02     EQU $184
  559. color03    EQU $186
  560. color04    EQU $188
  561. color05    EQU $18a
  562. color06    EQU $18c
  563. color07    EQU $18e
  564. color08    EQU $190
  565. color09    EQU $192
  566. color10    EQU $194
  567. color11    EQU $196
  568. color12    EQU $198
  569. color13    EQU $19a
  570. color14    EQU $19c
  571. color15    EQU $19e
  572. color16    EQU $1a0
  573. color17    EQU $1a2
  574. color18    EQU $1a4
  575. color19    EQU $1a6
  576. color20    EQU $1a8
  577. color21    EQU $1aa
  578. color22    EQU $1ac
  579. color23    EQU $1ae
  580. color24     EQU $1b0
  581. color25    EQU $1b2
  582. color26    EQU $1b4
  583. color27    EQU $1b6
  584. color28    EQU $1b8
  585. color29    EQU $1ba
  586. color30    EQU $1bc
  587. color31    EQU $1be
  588. diskreg    EQU $bfd100
  589. keydat    EQU $bfec01
  590. keyint    EQU $bfed01
  591. ctrla    EQU $bfee01
  592. ctrlb    EQU $bfef01
  593. ciatl    EQU $bfe401
  594. ciath    EQU $bfe501
  595. cia_a    EQU $bfe001        ;disk input bits
  596. cia_b    EQU $bfd100        ;disk output bits
  597.  
  598.